Public Class frmRTFHighLight
 
    'Eingabe der Worte für Highlight-Darstellung
    Dim WithEvents txtHigh As New TextBox With
        {.Parent = Me, .Left = 10, .Top = 10, .Width = 300}
 
    Dim rtbHigh As New RichTextBox With
        {.Parent = Me, .Left = 10, .Top = 50, .Width = 300, .Height = 300, _
          .Multiline = True}
 
    Dim txtHighlight As String = ""
 
 
    Private Sub frmRTFHighLight_Load(sender As Object, e As EventArgs) Handles _
      MyBase.Load
 
        'Beispieltext
        rtbHigh.Text = "Ene mene miste," & vbCrLf & "was rappelt in der Kiste?" _
          &
            vbCrLf & "Ene mene Meck" & vbCrLf & "und Du bist weg"
        rtbHigh.AppendText(vbCrLf & vbCrLf & rtbHigh.Text)
    End Sub
 
 
    Private Sub txtHigh_KeyDown(sender As Object, e As KeyEventArgs) Handles _
      txtHigh.KeyDown
 
        If e.KeyCode = Keys.Return Then
            'bestehenden Highlight-Text löschen
            SelectText(txtHighlight, False)
            txtHighlight = txtHigh.Text
            'neuen Text Highlight darstellen
            SelectText(txtHighlight, True)
        End If
    End Sub
 
 
    Private Sub SelectText(ByVal txt As String, ByVal showselect As Boolean)
 
        With rtbHigh
            If String.IsNullOrWhiteSpace(txt) Then Exit Sub
 
            Dim i As Integer = -txt.Length - 1
 
            'Suchschleife
            Do
                i = .Find(txt,
                          i + txt.Length + 1,
                          .Text.Length,
                          RichTextBoxFinds.WholeWord)
                If i >= 0 Then
                    .SelectionStart = i
                    .SelectionLength = txt.Length
 
                    If Not showselect Then
                        'normaleDarstellung
                        .SelectionColor = .ForeColor
                        .SelectionFont = .Font
                    Else
                        'Highlight-Darstellung
                        .SelectionColor = Color.Blue
                        .SelectionFont = New Font("Arial", 10, FontStyle.Bold)
                    End If
 
                    .SelectionLength = 0
                End If
            Loop While i >= 0 AndAlso i < .Text.Length - Txt.Length
        End With
    End Sub
 
End Class